void setup() 
{ 
  Serial.begin(115200); 

  Serial.println(F("Internal Temperature Sensor")); 
} 

void loop() 
{ 
  // Show the temperature in degrees Celcius. 
  Serial.println(GetTemp(),2); 
  delay(1000); 
} 

float GetTemp(void) 
{ 
  unsigned int wADC; 
  double t; 

  // The internal temperature has to be used 
  // with the internal reference of 1.1V. 
  // Channel 8 can not be selected with 
  // the analogRead function yet. 

  // Set the internal reference and mux. 
  ADMUX = 0xC8; 
  ADCSRA |= (1<<ADEN);  // enable the ADC 

  delay(20);            // wait for voltages to become stable. 

  ADCSRA |= (1<<ADSC);  // Start the ADC 

  // Detect end-of-conversion 
     while (ADCSRA & (1<<ADSC)); 

//wADC = ADCL | (ADCH << 8);
  // Reading register "ADCW" takes care of how to read ADCL and ADCH. 
  wADC = ADCW; 
//  Serial.println( wADC); 
  // The offset of 324.31 could be wrong. It is just an indication. 
  t = (wADC - 324.31 ) / 1.22; 

  // The returned temperature is in degrees Celcius. 
  return (t); 
}